ParsX.com
پذیرش پروژه از دانشجویی ... تا سازمانی 09376225339
 
   ProfileProfile   Log in to check your private messagesLog in to check your private messages  |  FAQFAQ   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups Log inLog in   RegisterRegister 

نحوه حركت نمايش سيگنال روي نمودار

 
Post new topic   Reply to topic    ParsX.com Forum Index -> ويژوال بيسيك .NET
View previous topic :: View next topic  
Author Message
moghimi
مهمون يكي دو روزه


Joined: 07 Dec 2005
Posts: 14
Location: iran- tehran

PostPosted: Sun Jan 01, 2006 12:03 am    Post subject: نحوه حركت نمايش سيگنال روي نمودار Reply with quote

سلام
به چه صورتي ميشه كه ما سيگنالي رو كه روي نمودار نمايش ميديم حركت بديم؟
(محيط نمايش نمودار از add كردن كامپوننت mathwork:strip chat روي فرم قرار ميگيره)
من خودم اين پيشنهاد رو دارم كه از سمت راست پيكسلها رو پاك كنيم و از سمت چپ شيفت بديم و در سمت راست كه پاك كرديم مقدار چديد رو بديم كه نمودار بعدي وارد بشه
در ضمن مقدار دهي به اين پيكسلها با چه دستوريه؟
ممنون
Back to top
unknown
مدير بخش ويژوال بيسيك
مدير بخش ويژوال بيسيك


Joined: 05 Dec 2004
Posts: 439
Location: Tehran

PostPosted: Sun Jan 01, 2006 2:26 pm    Post subject: Reply with quote

سلام
یه پروژه ی خوب
کد زیر رو در notepad کپی کنید و با پسوند .cls ذخیره کنید

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Cls_diagram"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Public HorzSplits As Long
Public VertSplits As Long
Public Max As Single 'Max value

Private ValueArray() As Single 'Array to hold values
Private mem_LineColor As Long
Private mem_GridColor As Long
Private mem_ShowGrid As Boolean
Private mem_pBox As PictureBox
Private mem_pBoxHeight As Long
Private mem_pBoxWidth As Long
Private mem_movingGrid As Boolean
Private StartPosition As Long 'Needed to not to display first zero values when starting a new diagram
Private GridPosition As Long

Public Enum ENUM_DIAGRAMTYPE
    TYPE_LINE = 0
    TYPE_POINT = 1
End Enum
Public DiagramType As ENUM_DIAGRAMTYPE 'Type of diagram (line or point)

Const const_tolerance = 0.0001 'Used to fix last line tolerance problem in some cases

Public Function InitDiagram(pBox As PictureBox, LineColor As Long, ShowGrid As Boolean, Optional GridColor As Variant, Optional MovingGrid As Variant)
   
    pBox.ScaleMode = vbPixels 'Set pixel scale mode
   
    mem_LineColor = LineColor
    mem_ShowGrid = ShowGrid
   
    mem_pBoxHeight = pBox.ScaleHeight
    mem_pBoxWidth = pBox.ScaleWidth
   
    'If user didn't give a grid color, we are using default (dark green) color
    If IsMissing(GridColor) Then
        mem_GridColor = RGB(0, 130, 0) 'Dark green
    Else:
        mem_GridColor = GridColor
    End If
   
    'If user didn't give a movingGrid parameter, we are using default (off)
    If IsMissing(MovingGrid) Then
        mem_movingGrid = False
    Else:
        mem_movingGrid = MovingGrid
    End If
   
    Set mem_pBox = pBox 'Save picturebox, so we dont need to ask it again
   
    'Allocate array to hold all diagram values (value per pixel)
    ReDim ValueArray(mem_pBoxWidth - 1)
   
    StartPosition = mem_pBoxWidth - 1
   
    GridPosition = 0
   
End Function
Public Sub AddValue(value As Single)
   
    Dim l As Long
   
    'Check if InitDiagram has not been executed yet
    If mem_pBox Is Nothing Then
        'Failed! (exit function)
        Exit Sub
    End If
   
    'Move all values from array one position lower
    For l = 1 To mem_pBoxWidth - 1
        ValueArray(l - 1) = ValueArray(l)
    Next
   
    'Max can't be 0 or smaller
    If Max <= 0 Then Max = 1
   
    'Add new value to the last element of array
    ValueArray(l - 1) = mem_pBoxHeight - ((value / Max) * mem_pBoxHeight)
   
    If StartPosition >= 1 Then StartPosition = StartPosition - 1
   
    GridPosition = GridPosition - 1
End Sub
Public Sub RePaint()

    Dim x As Single
    Dim y As Single
    Dim l As Long
   
    'Check if InitDiagram has not been executed yet
    If mem_pBox Is Nothing Then
        'Failed! (exit sub)
        Exit Sub
    End If

    'Create background image
    'First clear hole picture box, then draw grid if set, then draw diagram
   
    mem_pBox.Cls 'Clear picturebox
   
    'Draw grid if set
    If (mem_ShowGrid) Then
        mem_pBox.ForeColor = mem_GridColor
       
        'Draw vertical lines with or without using gridposition
        If (mem_movingGrid) Then
            For x = GridPosition To mem_pBoxWidth - 1 Step ((mem_pBoxWidth - 1) / (VertSplits + 1)) - const_tolerance
                mem_pBox.Line (x, 0)-(x, mem_pBoxHeight)
            Next
        Else:
            For x = 0 To mem_pBoxWidth - 1 Step ((mem_pBoxWidth - 1) / (VertSplits + 1)) - const_tolerance
                mem_pBox.Line (x, 0)-(x, mem_pBoxHeight)
            Next
        End If
       
        For y = 0 To mem_pBoxHeight - 1 Step ((mem_pBoxHeight - 1) / (HorzSplits + 1)) - const_tolerance
            mem_pBox.Line (0, y)-(mem_pBoxWidth, y)
        Next
        'Reset gridposition, when first line is not visible anymore
        If GridPosition <= -Int((mem_pBoxWidth - 1 / (HorzSplits + 1))) Then
            GridPosition = 0
        End If
    End If
   
    'Draw line diagram only if theres 2 or more values defined
    If StartPosition <= mem_pBoxWidth - 1 Then
        mem_pBox.ForeColor = mem_LineColor
       
        Select Case DiagramType
           
            Case TYPE_LINE
            For l = StartPosition + 1 To mem_pBoxWidth - 2
                mem_pBox.Line (l, ValueArray(l))-(l + 1, ValueArray(l + 1))
            Next
           
            Case TYPE_POINT
            For l = StartPosition + 1 To mem_pBoxWidth - 2
                mem_pBox.PSet (l + 1, ValueArray(l + 1))
            Next
        End Select
       
    End If

End Sub



کد زیر رو هم با پسوند .frm ذخیره کنید بعد هر دو فایل رو در یک پروژه ی vb اضافه کنید تا برنامه به درستی کار کند

VERSION 5.00
Begin VB.Form Form_main
   Caption         =   "Pure VB diagram monitors"
   ClientHeight    =   5175
   ClientLeft      =   1800
   ClientTop       =   1965
   ClientWidth     =   6090
   LinkTopic       =   "Form1"
   ScaleHeight     =   5175
   ScaleWidth      =   6090
   Begin VB.Frame Frame2
      Caption         =   "Point"
      Height          =   2235
      Left            =   120
      TabIndex        =   3
      Top             =   2400
      Width           =   5835
      Begin VB.PictureBox Picture_point2
         BackColor       =   &H00000000&
         BorderStyle     =   0  'None
         CausesValidation=   0   'False
         ClipControls    =   0   'False
         Height          =   1695
         Left            =   2940
         ScaleHeight     =   113
         ScaleMode       =   3  'Pixel
         ScaleWidth      =   181
         TabIndex        =   6
         Top             =   300
         Width           =   2715
      End
      Begin VB.PictureBox Picture_point
         BackColor       =   &H00000000&
         BorderStyle     =   0  'None
         CausesValidation=   0   'False
         ClipControls    =   0   'False
         Height          =   1695
         Left            =   180
         ScaleHeight     =   113
         ScaleMode       =   3  'Pixel
         ScaleWidth      =   181
         TabIndex        =   4
         Top             =   300
         Width           =   2715
      End
   End
   Begin VB.Timer Timer1
      Interval        =   500
      Left            =   3720
      Top             =   4680
   End
   Begin VB.CommandButton Command1
      Caption         =   "Start"
      Height          =   315
      Left            =   4380
      TabIndex        =   2
      Top             =   4740
      Width           =   1575
   End
   Begin VB.Frame Frame1
      Caption         =   "Line"
      Height          =   2235
      Left            =   120
      TabIndex        =   0
      Top             =   120
      Width           =   5835
      Begin VB.PictureBox Picture_line2
         BackColor       =   &H00000000&
         BorderStyle     =   0  'None
         CausesValidation=   0   'False
         ClipControls    =   0   'False
         Height          =   1695
         Left            =   2940
         ScaleHeight     =   113
         ScaleMode       =   3  'Pixel
         ScaleWidth      =   181
         TabIndex        =   5
         Top             =   300
         Width           =   2715
      End
      Begin VB.PictureBox Picture_line
         BackColor       =   &H00000000&
         BorderStyle     =   0  'None
         CausesValidation=   0   'False
         ClipControls    =   0   'False
         Height          =   1695
         Left            =   180
         ScaleHeight     =   113
         ScaleMode       =   3  'Pixel
         ScaleWidth      =   181
         TabIndex        =   1
         Top             =   300
         Width           =   2715
      End
   End
End
Attribute VB_Name = "Form_main"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
''''''''''''''''''''''''''''''''''''
'Simple diagrams
'Just add new reference to cls_diagram!
'By Sami Riihilahti
'Free to use at any case!
''''''''''''''''''''''''''''''''''''
Public linediagram As New Cls_linediagram

Public linediagram As New Cls_diagram
Public linediagram2 As New Cls_diagram
Public pointdiagram As New Cls_diagram
Public pointdiagram2 As New Cls_diagram
Public tancounter As Single 'We are using this just to create tan diagrams

Private Sub Command1_Click()

    'Create all 4 diagrams. See what options we have when calling .InitDiagram()
   
    '.InitDiagram picturebox, linecolor, showgrid, gridcolor, movinggrid
    'picturebox = the picturebox in which to add the diagram
    'linecolor = line color
    'showgrid = grid ON/OFF
    'gridcolor = [optional] grid color (default=dark green)
    'movinggrid = [optional] boolean true/false of moving grid (default=false)
   
    With linediagram
        .InitDiagram Picture_line, RGB(0, 255, 0), True
        .Max = 10
        .HorzSplits = 9
        .VertSplits = 9
        .DiagramType = TYPE_LINE
        .RePaint
    End With
    With pointdiagram
        .InitDiagram Picture_point, RGB(0, 255, 0), True
        .Max = 20
        .HorzSplits = 9
        .VertSplits = 9
        .DiagramType = TYPE_POINT
        .RePaint
    End With
    With linediagram2
        .InitDiagram Picture_line2, RGB(255, 255, 0), True, , True
        .Max = 100
        .HorzSplits = 9
        .VertSplits = 9
        .DiagramType = TYPE_LINE
        .RePaint
    End With
    With pointdiagram2
        .InitDiagram Picture_point2, RGB(0, 255, 255), True, RGB(100, 0, 0), True
        .Max = 10
        .HorzSplits = 9
        .VertSplits = 9
        .DiagramType = TYPE_POINT
        .RePaint
    End With
   
End Sub

Private Sub Picture_line_Paint()
    linediagram.RePaint
End Sub

Private Sub Picture_line2_Click()
    linediagram2.RePaint
End Sub

Private Sub Picture_point_Paint()
    pointdiagram.RePaint
End Sub

Private Sub Picture_point2_Click()
    pointdiagram.RePaint
End Sub

Private Sub Timer1_Timer()

    'Just randomize a new value in this sample
    Dim value As Single
    tancounter = tancounter + 0.1
    value = Tan(tancounter) + 2
   
    linediagram.AddValue value
    linediagram2.AddValue value
    pointdiagram.AddValue value
    pointdiagram2.AddValue value
    linediagram.RePaint
    linediagram2.RePaint
    pointdiagram.RePaint
    pointdiagram2.RePaint
End Sub
Back to top
moghimi
مهمون يكي دو روزه


Joined: 07 Dec 2005
Posts: 14
Location: iran- tehran

PostPosted: Mon Jan 02, 2006 4:34 pm    Post subject: Reply with quote

سلام
محيط سياه نمايش توسط چه كنترلي روي فرم قرار ميگيره و اطلاعا ت سيگنال با چه دستوري نمايش داده ميشه؟ در ضمن اين پروژه براي نمايش چه سيگنالي بوده؟
ممنون از راهنماييتون
Back to top
SAJAD_MIRZA
مهمون يكي دو روزه


Joined: 20 Dec 2005
Posts: 21

PostPosted: Tue Jan 03, 2006 9:17 pm    Post subject: Reply with quote

خیلی باحال بود
چطور میشه یه موج دلخواه مثلا سیکنالهای یه فایل صوتی رو رسم کرد (تقریبا مثل Sound Recorder ویندوز)
Back to top
unknown
مدير بخش ويژوال بيسيك
مدير بخش ويژوال بيسيك


Joined: 05 Dec 2004
Posts: 439
Location: Tehran

PostPosted: Wed Jan 04, 2006 3:03 am    Post subject: Reply with quote

فایل های wave به شکلی هستند که به راحتی (الکی) می شه نمودار امواجشون رو رسم کرد.

اگه وقت کنم پروژه ی اونم براتون می زارم
Back to top
vahid_ve
دوست آشناي سايت


Joined: 05 Feb 2006
Posts: 85

PostPosted: Thu Aug 10, 2006 8:27 pm    Post subject: Reply with quote

unknown wrote:
فایل های wave به شکلی هستند که به راحتی (الکی) می شه نمودار امواجشون رو رسم کرد.

اگه وقت کنم پروژه ی اونم براتون می زارم


پس بزار دیگه

Wink
Back to top
Display posts from previous:   
Post new topic   Reply to topic    ParsX.com Forum Index -> ويژوال بيسيك .NET All times are GMT + 3.5 Hours
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum